Oppolzer - Informatik / Blog

Die Mails aus den Mailing-Listen werden in einer ähnlichen Form
dargestellt wie in den Archiven, z.B. IBM-MAIN-Archiv.

Ich schreibe die Informationen in eine Datei, zusammen mit den
entsprechenden Metainformationen des jeweiligen Beitrags, und erstelle
dann daraus mit einem REXX-Skript die entsprechenden HTML-Seiten.

Beispiel:

In der Datei steht:

file=blog_150108a.htm
desc=IBM-MAIN - Probleme mit Testläufen auf produktiven Umgebungen
link=https://listserv.ua.edu/cgi-bin/wa?A2=ibm-main;9f84d7c2.1501
title=Re: How Does Your Shop Limit Testing in the Production LPAR
date=2015.01.08 09:55:41

sowie dann der Text des Beitrags.

Daraus generiert das REXX-Skript die entsprechende HTML-Seite
blog_150108a.htm und außerdem den Link auf der Blog-Master-Seite,
von der aus alle Blog-Beiträge erreichbar sind.

Hier ist das REXX-Skript:


/* rexx */

trace off

/************************************************/
/*                                              */
/*   Dateien fuer BLOG erzeugen                 */
/*                                              */
/************************************************/

say "Erzeugen der Dateien für den Blog"

"@if exist job8.htm erase job8.htm"

datenfile = "blog.dat"
mstjob = "job8.mst"
outfile1 = "job8.htm"

bodyinp = 0
zeilennr = 0
body. = ""
body.0 = 0

do while lines(mstjob) > 0

   zeiljob = linein(mstjob)

   if zeiljob = "$files$" then do
      call workfiles
   end
   else do
      x = lineout(outfile1, zeiljob)
   end

end

x = lineout(outfile1)

say
say "... fertig !!!"

exit 0



workfiles:

do while lines(datenfile) > 0

   zeilennr = zeilennr + 1

   zeile = linein(datenfile)
   daten = zeile

   if bodyinp = 1 then do
      if left(daten, 8) = "endbody=" then do
         bodyinp = 0
         call work
         iterate
      end
      else do
         body.0 = body.0 + 1
         anzbody = body.0
         body.anzbody = daten
         iterate
      end
   end

   if daten = "" then
      iterate

   if left(daten, 5) = "file=" then do
      outfile = substr(daten, 6)
      iterate
   end

   if left(daten, 5) = "desc=" then do
      desc = substr(daten, 6)
      iterate
   end

   if left(daten, 5) = "from=" then do
      from = substr(daten, 6)
      iterate
   end

   if left(daten, 6) = "reply=" then do
      reply = substr(daten, 7)
      iterate
   end

   if left(daten, 5) = "link=" then do
      link = substr(daten, 6)
      iterate
   end

   if left(daten, 6) = "title=" then do
      title = substr(daten, 7)
      iterate
   end

   if left(daten, 5) = "date=" then do
      date = substr(daten, 6)
      iterate
   end

   if left(daten, 5) = "body=" then do
      bodyinp = 1
      body.0 = 0
      iterate
   end

   say "Fehler in Zeile "zeilennr
   say "Inhalt der Zeile "zeile

end

return



work:

say
say "work aufgerufen"
say "file  = "outfile
say "desc  = "desc
say "from  = "from
say "reply = "reply
say "link  = "link
say "title = "title
say "date  = "date
say "body  = "anzbody "Zeilen"

outz = '<A HREF="'outfile'">'
x = lineout(outfile1, outz)
outz = date" - "desc
x = lineout(outfile1, outz)
outz = "</A>"
x = lineout(outfile1, outz)
outz = "<br/>"
x = lineout(outfile1, outz)

mstblog = "blog.mst"
outfile2 = outfile

"@if exist "outfile2" erase "outfile2

do while lines(mstblog) > 0

   zeilb = linein(mstblog)

   if pos("$", zeilb) <> 0 then do
      call work_blogline
   end
   else do
      x = lineout(outfile2, zeilb)
   end

end

x = lineout(outfile2)
x = lineout(mstblog)

return



work_blogline:

if pos("$body$", zeilb) <> 0 then do
   do i = 1 to anzbody
      outz = body.i
      x = lineout(outfile2, outz)
   end
   return
end

if pos("$link$", zeilb) <> 0 then do
   outz = '<a href="'link'">'
   x = lineout(outfile2, outz)
   return
end

if pos("$title$", zeilb) <> 0 then do
   outz = title
   x = lineout(outfile2, outz)
   return
end

if pos("$from$", zeilb) <> 0 then do
   outz = '<p>'from'</p>'
   x = lineout(outfile2, outz)
   return
end

if pos("$reply$", zeilb) <> 0 then do
   outz = '<p>'reply'</p>'
   x = lineout(outfile2, outz)
   return
end

if pos("$date$", zeilb) <> 0 then do
   outz = '<p>'date'</p>'
   x = lineout(outfile2, outz)
   return
end

return